##########################################################################
#       $Id: .cshrc,v 1.6 2002/04/11 12:29:43 simonb Exp $
#       (c)$Date: 2002/04/11 12:29:43 $
#       simonbs .cshrc phile...
#       #include disclaim.h
#
#       The latest version of this file can *always* be found
#       at http://kaizo.org/~simonb/dot.cshrc
#
# Permission to use, copy, modify, and distribute this software for
# any purpose with or without fee is hereby granted, provided that the
# above copyright notice, this permission notice, and the following
# disclaimer appear on all copies.
#
# This software is provided by Simon B on as is basis and all
# warranties expressed or implied are disclaimed.  In no event
# shall the author be held liable for any direct or indirect
# damages however caused arising from the use of this software.
#
#######################################################################
###     This is where you can store personal info, create this file!!!
###     e.g., alias blob ssh -l mylogin blob.domain
#######################################################################

if ( -f ${home}/.cshrc-personal ) source ${home}/.cshrc-personal

#######################################################################
###     Default Aliases...
#######################################################################
alias mail      Mail
alias z         suspend
alias h         history 25
alias j         jobs -l
alias la        ls -al
alias lf        ls -FA
alias ll        ls -lA
alias l         ls -l
alias bzip      'bzip2 -vv'
alias bzip2     'bzip2 -vv'
alias arin      'whois -h whois.arin.net'
alias ripe      'whois -h whois.ripe.net'
alias apnic     'whois -h whois.apnic.net'
alias ipof      'host -a'
alias nameof    'host -a'
alias host      'host -a'
alias crypt     'pgp -i'
alias tcpdump6  'tcpdump proto ipv6'
alias fuckit    logout
alias mroe      more
alias shutdown  'shutdown -r +10 "fuct again..."'
alias gnu       'ftp ftp://ftp.mirror.ac.uk/sites/ftp.gnu.org/pub/gnu/'
alias today     "date '+%d%h%y'"
alias mess      'clear ; tail -f /var/log/messages'
alias ff        'find . -name $*'
alias .         'pwd'
alias ..        'cd ..'
alias -         'cd -'
alias restart  'clear ; exec tcsh'
alias maek      'make'
alias alais     'alias'
alias sl        'ls -l'
alias rfcget    'cd /tmp && ftp http://www.mirror.ac.uk/sites/ftp.isi.edu/in-notes/rfc\!^.txt && more rfc\!^.txt'
alias scp       'scp -prvC'
alias bindv     'nslookup -q=txt -class=CHAOS version.bind. '
alias df        'df -k'
alias ssh       'ssh -C -x -c blowfish'
alias ftp       'ftp -v -r 10 '
alias rgrep     'find ./ -type file | xargs grep '
alias more      'less'
alias m         'more'
alias t         'tail'
alias tf        'tail -f'
alias open      'chmod go+r'
alias shut      'chmod go-r'
alias close     'chmod g-w,o-rwx'
alias ma        'make all'
alias mc        'make clean'
alias mdc       'make distclean'
alias mde       'make depend'
alias mi        'make install'
alias ms        'make spotless'
alias nuke      'set j = `ps x | grep \!* | grep -v grep`; \
                  kill -9 $j[1]; echo "kill -9 $j[1]"'


#########################################################################
###     Environment Variables
#########################################################################
setenv  EDITOR          vi
setenv  EXINIT          'set autoindent noai'
setenv  PAGER           less
setenv  ORGANIZATION    "Kaizo Dot Org"
setenv	MAIL		'~/Mailbox'
##########################################################################

##########################################################################
###     Set up paths and other specifics...
###     create the biggest st00pidest path know to man....
##########################################################################
#
set path = (/usr/arm/{bin,arm-linux/bin} ~/bin /bin /sbin /command /usr/local/{bin,sbin} \
        /usr/{sbin,bin,X11R6/bin,pkg/bin,pkg/sbin,games,djb/bin,djb/dnscache/bin} /usr/local/{j2re1.4.0/bin,j2sdk1.4.0/bin} )


if ($?prompt) then
        # An interactive shell -- set some stuff up
        set filec
        set history = 100000
        set ignoreeof
        set mch = `hostname -s`
        set prompt = "[%B%@%b]%B$mch% "
        set watch = ( 0 any any )
        set who="%n has %a %l from %M."
        set autolist
        set listjobs
        set printexitvalue
        set fignore=(.o)
        set time=(8 "\
        Time spent in user mode   (CPU seconds) : %Us\
        Time spent in kernel mode (CPU seconds) : %Ss\
        Total time                              : %Es\
        CPU utilisation (percentage)            : %P\
        Times the process was swapped           : %W\
        Times of major page faults              : %F\
        Times of minor page faults              : %R")
        set color
        #set mail=2 ~/Mailbox
        set visiblebell
        set nobeep
        umask 22
        # i'm helpful, and bored
        mesg y
endif

############################################################################
###     Resource limits, fairly sensible...
############################################################################
limit coredumpsize 0

###     EOF     ####